Защита MikroTik: базовые правила Firewall для RouterOS 7

Роутер MikroTik с настройками по умолчанию защищён неплохо, но после сброса конфигурации или на облачном роутере CHR файрвол пуст, и устройство с публичным IP-адресом начинают атаковать в первые же минуты. Ниже — минимальный набор правил, который закрывает роутер и сеть за ним, с объяснением каждого шага.
Как устроен файрвол RouterOS
Правила обрабатываются сверху вниз до первого совпадения, поэтому порядок важен. Основных цепочек три:
- input — трафик, адресованный самому роутеру: WinBox, SSH, DNS, VPN;
- forward — трафик, проходящий через роутер: из локальной сети в интернет и обратно;
- output — трафик, который создаёт сам роутер.
В примерах ether1 — интерфейс провайдера (WAN), bridge — локальная сеть 192.168.88.0/24. Подставьте свои значения.
Шаг 1. Списки интерфейсов
Правила удобнее писать не для конкретных портов, а для списков:
/interface list
add name=WAN
add name=LAN
/interface list member
add list=WAN interface=ether1
add list=LAN interface=bridge
Шаг 2. Защита самого роутера (input)
/ip firewall filter
add chain=input action=accept connection-state=established,related,untracked comment="Established"
add chain=input action=drop connection-state=invalid comment="Drop invalid"
add chain=input action=accept protocol=icmp comment="ICMP"
add chain=input action=accept in-interface-list=LAN comment="From LAN"
add chain=input action=drop comment="Drop everything else"
Что делают правила:
- пропускают пакеты уже установленных соединений — это основная часть трафика, она обрабатывается первой и не нагружает процессор;
- отбрасывают некорректные пакеты;
- разрешают ping — он нужен для диагностики;
- разрешают доступ к роутеру из локальной сети;
- запрещают всё остальное, в том числе любые подключения из интернета.
Шаг 3. Защита локальной сети (forward)
/ip firewall filter
add chain=forward action=fasttrack-connection connection-state=established,related hw-offload=yes comment="FastTrack"
add chain=forward action=accept connection-state=established,related,untracked comment="Established"
add chain=forward action=drop connection-state=invalid comment="Drop invalid"
add chain=forward action=drop connection-state=new connection-nat-state=!dstnat in-interface-list=WAN comment="Drop from WAN not DSTNAT"
Последнее правило запрещает любые новые подключения из интернета в локальную сеть, кроме тех, для которых вы явно настроили проброс портов. FastTrack ускоряет обработку установленных соединений в несколько раз.
Шаг 4. NAT
Если роутер раздаёт интернет локальной сети, нужно правило маскарадинга:
/ip firewall nat
add chain=srcnat action=masquerade out-interface-list=WAN comment="Masquerade"
Шаг 5. Доступ к роутеру извне
Правила выше полностью закрывают управление из интернета. Если удалённый доступ нужен, есть три способа — от самого надёжного к наименее желательному.
Через VPN
Поднимите на роутере WireGuard и управляйте им только через туннель. Разрешите порт VPN, разместив правило выше запрещающего:
/ip firewall filter
add chain=input action=accept protocol=udp dst-port=13231 place-before=[find comment="Drop everything else"] comment="WireGuard"
Настройка туннеля описана в руководстве по WireGuard в RouterOS.
С доверенных адресов
/ip firewall address-list
add list=admins address=198.51.100.7
/ip firewall filter
add chain=input action=accept src-address-list=admins protocol=tcp dst-port=8291,22 place-before=[find comment="Drop everything else"] comment="Admins"
С защитой от перебора
Если адрес администратора непостоянный, добавьте защиту: после трёх новых подключений за минуту адрес блокируется на сутки.
/ip firewall filter
add chain=input action=drop src-address-list=blacklist place-before=0 comment="Blacklist"
add chain=input action=add-src-to-address-list protocol=tcp dst-port=22,8291 connection-state=new src-address-list=stage2 address-list=blacklist address-list-timeout=1d place-before=[find comment="Drop everything else"]
add chain=input action=add-src-to-address-list protocol=tcp dst-port=22,8291 connection-state=new src-address-list=stage1 address-list=stage2 address-list-timeout=1m place-before=[find comment="Drop everything else"]
add chain=input action=add-src-to-address-list protocol=tcp dst-port=22,8291 connection-state=new address-list=stage1 address-list-timeout=1m place-before=[find comment="Drop everything else"]
add chain=input action=accept protocol=tcp dst-port=22,8291 place-before=[find comment="Drop everything else"] comment="Management"
Шаг 6. Отключите лишние службы
Файрвол не единственный рубеж. Отключите всё, чем не пользуетесь:
/ip service
disable telnet,ftp,www,api,api-ssl
set ssh address=192.168.88.0/24
set winbox address=192.168.88.0/24
Параметр address дополнительно ограничивает адреса, с которых служба принимает подключения. Если нужен доступ извне, добавьте в список свои адреса или подсеть VPN.
Отключите обнаружение соседей и подключение по MAC-адресу на внешнем интерфейсе:
/ip neighbor discovery-settings set discover-interface-list=LAN
/tool mac-server set allowed-interface-list=LAN
/tool mac-server mac-winbox set allowed-interface-list=LAN
Закройте DNS-сервер роутера от запросов из интернета. Правило Drop everything else в цепочке input уже это делает; если вы его не используете, запретите порт 53 на внешнем интерфейсе явно — открытый DNS-резолвер используют для DDoS-атак.
Шаг 7. Учётные записи
- Создайте нового администратора с надёжным паролем и удалите стандартную запись
admin:
/user add name=myadmin group=full password="надёжный_пароль"
/user remove admin
- Для SSH используйте ключи вместо паролей.
- Отключите неиспользуемые пакеты и интерфейсы.
Шаг 8. Обновления
Большинство массовых взломов MikroTik происходили через уязвимости в устаревших версиях RouterOS. Проверяйте обновления регулярно:
/system package update check-for-updates
/system package update install
/system routerboard upgrade
Последняя команда обновляет загрузчик на аппаратных роутерах; после неё нужна перезагрузка.
Проверка
Посмотрите счётчики правил — они показывают, какие правила срабатывают:
/ip firewall filter print stats
Проверьте, что из интернета роутер не отвечает на портах управления: с внешнего компьютера выполните nmap -Pn IP-адрес или воспользуйтесь онлайн-сканером портов.
Резервная копия конфигурации
После настройки сохраните конфигурацию в текстовом виде:
/export file=firewall-backup
Файл появится в разделе Files — скачайте его и храните отдельно от роутера.
Что дальше
- Уведомления в Telegram о событиях на роутере.
- Объединение офисов через WireGuard.
- Port knocking как дополнительный способ скрыть порты управления.


